跳至主内容

RabbitMQ 教程 - 远程过程调用 (RPC)

远程过程调用 (RPC)​

（使用 amqp Elixir 库）​

信息

先决条件​

本教程假设 RabbitMQ 已 安装 并在 localhost 上的 标准端口 (5672) 上运行。如果您使用不同的主机、端口或凭据，则需要调整连接设置。

哪里寻求帮助​

如果您在学习本教程时遇到困难，可以通过 GitHub Discussions 或 RabbitMQ 社区 Discord 联系我们。

在第二个教程中，我们学习了如何使用工作队列在多个工作进程之间分发耗时的任务。

但是，如果我们需要在远程计算机上运行一个函数并等待结果呢？嗯，那又是另一回事了。这种模式通常被称为远程过程调用或RPC。

在本教程中，我们将使用 RabbitMQ 来构建一个 RPC 系统：一个客户端和一个可扩展的 RPC 服务器。由于我们没有什么值得分发的耗时任务，我们将创建一个返回斐波那契数的虚拟 RPC 服务。

客户端接口​

为了说明 RPC 服务如何使用，我们将创建一个简单的客户端模块。它将包含一个名为 call 的函数，该函数发送 RPC 请求并阻塞直到收到响应。

result = FibonacciRpcClient.call(4)
IO.puts("fib(4) is #{result}")

关于 RPC 的说明​

尽管 RPC 在计算领域是一种相当普遍的模式，但它经常受到批评。当程序员不知道函数调用是本地的还是慢速的 RPC 时，就会出现问题。这样的混淆会导致系统不可预测，并增加调试的复杂性。滥用的 RPC 可能导致难以维护的意大利面条式代码，而不是简化软件。

牢记这一点，请考虑以下建议：

  • 确保明确哪些函数调用是本地的，哪些是远程的。
  • 记录你的系统。明确组件之间的依赖关系。
  • 处理错误情况。当 RPC 服务器长时间关闭时，客户端应该如何反应？

如果不确定，请避免使用 RPC。如果可能，你应该使用异步管道——而不是 RPC 类的阻塞，结果会异步推送到下一个计算阶段。

回调队列​

RabbitMQ 中的请求-应答模式涉及服务器和客户端之间的直接交互。

客户端发送请求消息，服务器用响应消息进行答复。

为了接收答复，我们需要在请求中发送一个“回调”队列名称。这样的队列通常是服务器命名的，也可以有一个众所周知的名称（客户端命名）。

然后，服务器将使用该名称通过默认交换机进行答复。

{:ok, %{queue: callback_queue}} = AMQP.Queue.declare(channel,
                                                     "",
                                                     exclusive: true)

AMQP.Basic.publish(channel,
                   "",
                   "rpc_queue",
                   request,
                   reply_to: callback_queue)
# ... and some code to read a response message from the callback_queue ...

消息属性​

AMQP 0-9-1 协议预定义了一组 14 个消息属性。大多数属性很少使用，除了以下几点：

  • persistent：将消息标记为持久（值为 true）或瞬时（任何其他值）。您可能还记得第二个教程中提到的这个属性。
  • content_type：用于描述编码的 mime 类型。例如，对于常用的 JSON 编码，通常的做法是将此属性设置为：application/json。
  • reply_to：通常用于命名一个回调队列。
  • correlation_id：用于将 RPC 响应与请求关联起来。

相关 ID​

为每个 RPC 请求创建一个回调队列效率低下。更好的方法是为每个客户端创建一个回调队列。

这会引发一个新问题：在该队列中收到响应后，并不清楚该响应属于哪个请求。这时就可以使用 correlation_id 属性。我们将为每个请求设置一个唯一的值。稍后，当我们收到回调队列中的消息时，我们会查看此属性，并根据它将响应与请求进行匹配。如果我们看到一个未知的 correlation_id 值，我们可以安全地丢弃该消息——它不属于我们的请求。

你可能会问，为什么我们应该忽略回调队列中的未知消息，而不是以错误告终？这是因为服务器端存在竞态条件的可能性。虽然不太可能，但 RPC 服务器可能在发送答复后，但在发送请求的确认消息之前就已死机。如果发生这种情况，重新启动的 RPC 服务器将再次处理该请求。因此，在客户端，我们必须优雅地处理重复的响应，并且 RPC 最好是幂等的。

总结​

我们的 RPC 将按如下方式工作：

  • 客户端启动时，它会创建一个排他的回调队列。
  • 对于 RPC 请求，客户端发送一个带有两个属性的消息：reply_to，设置为回调队列；correlation_id，设置为每个请求的唯一值。
  • 请求被发送到 rpc_queue 队列。
  • RPC 工作进程（也称为服务器）在该队列上等待请求。当出现请求时，它会执行任务，并使用 reply_to 字段中的队列将带有结果的消息发送回客户端。
  • 客户端等待回调队列上的数据。当出现消息时，它会检查 correlation_id 属性。如果它与请求中的值匹配，则将响应返回给应用程序。

总而言之​

rpc_server.exs 的代码

defmodule FibServer do
  def fib(0), do: 0
  def fib(1), do: 1
  def fib(n) when n > 1, do: fib(n-1) + fib(n-2)

  def wait_for_messages(channel) do
    receive do
      {:basic_deliver, payload, meta} ->
        {n, _} = Integer.parse(payload)
        IO.puts " [.] fib(#{n})"
        response = fib(n)

        AMQP.Basic.publish(channel,
                           "",
                           meta.reply_to,
                           "#{response}",
                           correlation_id: meta.correlation_id)
        AMQP.Basic.ack(channel, meta.delivery_tag)

        wait_for_messages(channel)
    end
  end
end

{:ok, connection} = AMQP.Connection.open
{:ok, channel} = AMQP.Channel.open(connection)

AMQP.Queue.declare(channel, "rpc_queue")
AMQP.Basic.qos(channel, prefetch_count: 1)
AMQP.Basic.consume(channel, "rpc_queue")
IO.puts " [x] Awaiting RPC requests"

FibServer.wait_for_messages(channel)

服务器代码相当直接。

  • (2-4) 我们声明了我们的斐波那契函数。（不要期望它能处理大数字，这可能是最慢的递归实现方式了）。
  • (25-28) 一如既往，我们首先建立连接并声明队列。
  • (29) 我们可能希望运行多个服务器进程。为了在多个服务器之间平均分配负载，我们需要设置 prefetch_count 设置。
  • (30) 我们等待来自 AMQP.Basic.consume 的消息，这是 RPC 服务器的核心。当收到请求时执行。它执行工作并将响应发送回去。

rpc_client.exs 的代码

defmodule FibonacciRpcClient do
  def wait_for_messages(_channel, correlation_id) do
    receive do
      {:basic_deliver, payload, %{correlation_id: ^correlation_id}} ->
        {n, _} = Integer.parse(payload)
        n
    end
  end
  def call(n) do
    {:ok, connection} = AMQP.Connection.open
    {:ok, channel} = AMQP.Channel.open(connection)

    {:ok, %{queue: queue_name}} = AMQP.Queue.declare(channel,
                                                     "",
                                                     exclusive: true)
    AMQP.Basic.consume(channel, queue_name, nil, no_ack: true)
    correlation_id =
      :erlang.unique_integer
      |> :erlang.integer_to_binary
      |> Base.encode64

    request = to_string(n)
    AMQP.Basic.publish(channel,
                       "",
                       "rpc_queue",
                       request,
                       reply_to: queue_name,
                       correlation_id: correlation_id)

    FibonacciRpcClient.wait_for_messages(channel, correlation_id)
  end
end

num =
  case System.argv do
    []    -> 30
    param ->
      {x, _} =
        param
        |> Enum.join(" ")
        |> Integer.parse
      x
  end

IO.puts " [x] Requesting fib(#{num})"
response = FibonacciRpcClient.call(num)
IO.puts " [.] Got #{response}"

客户端代码稍微复杂一些。

  • (4) 每次响应执行的 'wait_for_messages' 函数执行一个非常简单的任务，对于每条响应消息，它会检查 correlation_id 是否是我们正在寻找的那个。如果是，它会返回该值并停止监听其他消息。
  • (9) 接下来，我们定义了主要的 call 方法——它执行实际的 RPC 请求。
  • (10-13) 我们建立连接、通道，并声明一个专用的“回调”队列用于接收回复。
  • (16) 我们订阅“回调”队列，以便能够接收 RPC 响应。
  • (17) 在此函数中，首先生成一个唯一的 correlation_id 数字——'wait_for_messages' 函数将使用此值来捕获适当的响应。
  • (23) 接下来，我们发布请求消息，其中包含两个属性：reply_to 和 correlation_id。
  • (30) 至此，我们可以坐下来，等待正确的响应到来。

我们的 RPC 服务现在已准备就绪。我们可以启动服务器：

mix run rpc_server.exs
# => [x] Awaiting RPC requests

要请求一个斐波那契数，请运行客户端：

mix run rpc_client.exs
# => [x] Requesting fib(30)

所提出的设计并非 RPC 服务的唯一实现方式，但它有一些重要的优点。

  • 如果 RPC 服务器太慢，您可以通过运行另一个服务器来扩展。尝试在新的控制台中运行第二个 rpc_server.exs。
  • 在客户端，RPC 要求只发送和接收一条消息。不需要像 queue_declare 这样的同步调用。因此，RPC 客户端仅需一次网络往返即可完成一次 RPC 请求。

我们的代码仍然非常简单，并且没有试图解决更复杂（但重要）的问题，例如：

  • 如果没有任何服务器正在运行，客户端应该如何反应？
  • 客户端是否应该为 RPC 设置某种超时？
  • 如果服务器发生故障并引发异常，是否应将其转发给客户端？
  • 在处理前保护传入消息免受无效输入（例如检查边界）的影响。

如果你想进行实验，可能会发现管理 UI 对于查看队列很有用。

(rpc_client.exs 和 rpc_server.exs 的完整源代码)

© . This site is unofficial and not affiliated with VMware.