RabbitMQ 教程 - 路由

路由

（使用 amqp Elixir 库）

信息

先决条件

本教程假设 RabbitMQ 已安装并在 localhost 上的标准端口 (5672) 上运行。如果您使用不同的主机、端口或凭据，则需要调整连接设置。

哪里寻求帮助

如果您在学习本教程时遇到困难，可以通过 GitHub Discussions 或 RabbitMQ 社区 Discord 联系我们。

在上一篇教程中，我们构建了一个简单的日志系统。我们能够将日志消息广播给多个接收者。

在本教程中，我们将为其添加一项功能——我们将能够仅订阅一部分消息。例如，我们可以将仅关键错误消息定向到日志文件（以节省磁盘空间），同时仍然能够将所有日志消息打印到控制台。

绑定

在之前的示例中，我们已经创建了绑定。您可能还记得这样的代码

AMQP.Queue.bind(channel, queue_name, exchange_name)

绑定是交换机和队列之间的关系。这可以简单地理解为：队列对来自此交换机的消息感兴趣。

绑定可以接受一个额外的routing_key参数。为了避免与basic_publish参数混淆，我们将称之为binding key。以下是我们如何创建一个带有键的绑定：

AMQP.Queue.bind(channel, queue_name, exchange_name, routing_key: "black")

绑定 key 的含义取决于交换机类型。我们之前使用的 fanout 交换机只是忽略了它的值。

直连交换机

我们上一教程中的日志系统会将所有消息广播给所有消费者。我们希望扩展它，允许根据严重性过滤消息。例如，我们可能希望将日志消息写入磁盘的脚本仅接收严重错误，而不是在警告或信息日志消息上浪费磁盘空间。

我们使用了fanout交换器，它没有给我们太大的灵活性——它只能进行无脑广播。

我们将改用 direct 交换机。direct 交换机背后的路由算法很简单——消息会被发送到其 binding key 精确匹配消息的 routing key 的队列。

为了说明这一点，请考虑以下设置

在此设置中，我们可以看到 direct 交换机 X 绑定了两个队列。第一个队列绑定了绑定 key orange，第二个队列有两个绑定，一个绑定 key 是 black，另一个是 green。

在这种设置下，发布到具有路由 key orange 的交换机的消息将被路由到队列 Q1。具有路由 key black 或 green 的消息将发送到 Q2。所有其他消息将被丢弃。

多个绑定

使用相同的绑定 key 绑定多个队列是完全合法的。在我们的示例中，我们可以添加一个 X 和 Q1 之间的绑定，绑定 key 为 black。在这种情况下，direct 交换机将表现得像 fanout，并将消息广播给所有匹配的队列。路由 key 为 black 的消息将被传递给 Q1 和 Q2。

发送日志

我们将把这个模型用于我们的日志系统。我们将消息发送到 direct 交换机，而不是 fanout。我们将日志严重性作为 routing key。这样，接收脚本将能够选择它想要接收的严重性。让我们先关注发送日志。

像往常一样，我们需要先创建一个交换器。

AMQP.Exchange.declare(channel, "direct_logs", :direct)

我们已准备好发送消息

AMQP.Basic.publish(channel, "direct_logs", severity, message)

为了简化，我们将假设“严重性”可以是 info、warning 或 error 之一。

总而言之

emit_log_direct.exs的代码：

{:ok, connection} = AMQP.Connection.open
{:ok, channel} = AMQP.Channel.open(connection)

{severities, raw_message, _} =
  System.argv
  |> OptionParser.parse(strict: [info:    :boolean,
                                 warning: :boolean,
                                 error:   :boolean])
  |> case do
    {[], msg, _} -> {[info: true], msg, []}
    other -> other
  end

message =
  case raw_message do
    []    -> "Hello World!"
    words -> Enum.join(words, " ")
  end

AMQP.Exchange.declare(channel, "direct_logs", :direct)

for {severity, true} <- severities do
  severity = severity |> to_string
  AMQP.Basic.publish(channel, "direct_logs", severity, message)
  IO.puts " [x] Sent '[#{severity}] #{message}'"
end

AMQP.Connection.close(connection)

receive_logs_direct.exs的代码：

defmodule ReceiveLogsDirect do
  def wait_for_messages(channel) do
    receive do
      {:basic_deliver, payload, meta} ->
        IO.puts " [x] Received [#{meta.routing_key}] #{payload}"

        wait_for_messages(channel)
    end
  end
end

{:ok, connection} = AMQP.Connection.open
{:ok, channel} = AMQP.Channel.open(connection)

{severities, _, _} =
  System.argv
  |> OptionParser.parse(strict: [info:    :boolean,
                                 warning: :boolean,
                                 error:   :boolean])

AMQP.Exchange.declare(channel, "direct_logs", :direct)

{:ok, %{queue: queue_name}} = AMQP.Queue.declare(channel, "", exclusive: true)

for {severity, true} <- severities do
  binding_key = severity |> to_string
  AMQP.Queue.bind(channel, queue_name, "direct_logs", routing_key: binding_key)
end

AMQP.Basic.consume(channel, queue_name, nil, no_ack: true)

IO.puts " [*] Waiting for messages. To exit press CTRL+C, CTRL+C"

ReceiveLogsDirect.wait_for_messages(channel)

如果您只想将“警告”和“错误”（而不是“信息”）日志消息保存到文件，只需打开一个终端并输入：

# => mix run receive_logs_direct.exs --warning --error > logs_from_rabbit.log

如果您想在屏幕上看到所有日志消息，请打开一个新的终端并执行：

mix run receive_logs_direct.exs --info --warning --error
# => [*] Waiting for logs. To exit press CTRL+C, CTRL+C

例如，要发送一个 error 日志消息，只需键入：

mix run emit_log_direct.exs --error "Run. Run. Or it will explode."
# => [x] Sent '[error] Run. Run. Or it will explode.'

（emit_log_direct.exs和receive_logs_direct.exs的完整源代码）

继续学习教程 5，了解如何根据模式监听消息。

路由​

（使用 amqp Elixir 库）​

先决条件​

哪里寻求帮助​

绑定​

直连交换机​

多个绑定​

发送日志​

订阅​

总而言之​

路由